4D v15
LDAP Search
LDAP Search
| LDAP Search ( dnRootEntry ; filtro {; alcance {; atributos {; atributosEnArray}}} ) -> Resultado | ||||||||
| Parámetro | Tipo | Descripción | ||||||
| dnRootEntry | Cadena |
|
Nombre completo de la entrada de la raíz para iniciar la búsqueda | |||||
| filtro | Cadena |
|
Filtro de búsqueda LDAP | |||||
| alcance | Cadena |
|
Alcance de la búsqueda: "base" (por defecto), "one", o "sub" | |||||
| atributos | Array cadena |
|
Atributos a recuperar | |||||
| atributosEnArray | Array booleano |
|
True = fuerza el retorno de los atributos en un array; false = fuerza el retorno de los atributos en una variable simple | |||||
| Resultado | Objeto |
|
Atributos llave/valor | |||||
El comando LDAP Search busca la primera ocurrencia que coincida con los criterios definidos en el servidor LDAP objetivo. Este comando debe ser ejecutado dentro de una conexión a un servidor LDAP abierta con LDAP LOGIN; de lo contrario se devuelve un error 1003.
En dnRootEntry, pase el Distinguished Name del elemento raíz del servidor LDAP; la búsqueda se iniciará a partir de este elemento.
En filtro, pase el filtro de búsqueda LDAP a aplicar. La cadena filtro debe ser compatible con rfc2225. Puede pasar una cadena vacía "" para no filtrar la búsqueda; el "*" se soporta para buscar subcadenas.
En alcance, pase una de las siguientes constantes del tema "LDAP":
| Constante | Tipo | Valor | Comentario |
| LDAP root only | Texto | "base" | Buscar sólo en el elemento raíz definido por dnRootEntry (por defecto si se omite) |
| LDAP root and next | Texto | "one" | Buscar en el elemento la raíz definido por dnRootEntry y en las entradas posteriores directamente en un nivel |
| LDAP all levels | Texto | "sub" | Buscar en el elemento raíz definido por dnRootEntry y en todas las entradas posteriores |
En atributos, pase un array texto que contiene la lista de todos los atributos LDAP a recuperar a partir de las entradas encontradas. Por defecto, si se omite este parámetro, todos los atributos se recuperan.
Nota: tenga en cuenta que los nombres de atributos LDAP distinguen entre mayúsculas y minúsculas. Para más información sobre los atributos LDAP, puede consultar esta página que lista todos los atributos disponibles para MS Active directory.
Por defecto, el comando devuelve atributos como un array si se encuentran varios resultados, o como una variable si se encuentra un solo resultado. Los parámetros opcionales atributosEnArray permiten "forzar" el formato de los atributos devueltos en un array o como una variable para cada atributo definido:
- Cuando pase true en un elemento, el elemento correspondiente del parámetro atributos será devuelto en un array. Si se encuentra un solo valor, el comando devuelve un array con un solo elemento.
- Cuando pase false en un elemento, el elemento correspondiente del parámetro atributos será devuelto en una variable simple. Si se encuentran varias entradas, el comando devuelve sólo el primer elemento.
ARRAY TEXT($_tabAttributes;0)
APPEND TO ARRAY($_tabAttributes;"cn")
APPEND TO ARRAY($_tabAttributes;"phoneNumber")
LDAP LOGIN($url;$dn;$pwd)
$filter:="cn=*smith*"
$vfound:=LDAP Search($dnSearchRootEntry;$filter;LDAP all levels;$_tabAttributes)
LDAP LOGOUTQueremos obtener una array de todas las entradas que se encuentran en el atributo "memberOf":
C_OBJECT($entry)
ARRAY TEXT($_tabAttributes;0)
ARRAY BOOLEAN($_tabAttributes_asArray;0)
APPEND TO ARRAY($_tabAttributes;"cn")
APPEND TO ARRAY($_tabAttributes_asArray;False)
APPEND TO ARRAY($_tabAttributes;"memberOf")
APPEND TO ARRAY($_tabAttributes_asArray;True)
LDAP LOGIN($url;$login;$pwd;LDAP password plain text)
$entry:=LDAP Search($dnSearchRootEntry;"cn=adrien*";LDAP all levels;$_tabAttributes;$_tabAttributes_asArray)
LDAP LOGOUT
ARRAY TEXT($_arrMemberOf;0)
OB GET ARRAY($entry;"memberOf";$_arrMemberOf)
// en $_arrMemberOf tenemos un array que contiene todos los grupos de la entrada
Producto: 4D
Tema: Directorio Empresarial (LDAP)
4D v15 - Actualización (edición R-release) ( 4D v15)
Parent of : LDAP Search ( 4D v15)
