4D v15.4
GET FIELD RELATION
GET FIELD RELATION
| GET FIELD RELATION ( champN ; aller ; retour {; *} ) | ||||||||
| Paramètre | Type | Description | ||||||
| champN | Champ |
|
Champ de départ du lien | |||||
| aller | Entier long |
|
Statut du lien aller | |||||
| retour | Entier long |
|
Statut du lien retour | |||||
| * | Opérateur |
|
• Si passé : aller et retour retournent le statut courant effectif du lien (valeurs 2 ou 3 uniquement) • Si omis (défaut) : aller et retour peuvent retourner la valeur 1 si le lien n’a pas été modifié par programmation |
|||||
La commande GET FIELD RELATION permet de connaître le statut automatique/manuel du lien partant du champN pour le process courant. Tous les liens peuvent être consultés, y compris les liens déclarés automatiques dans la fenêtre de Structure.
- Passez dans champN le nom du champ de la table N d’où part le lien dont vous souhaitez connaître le statut. Si aucun lien ne part du champ champN, les paramètres aller et retour retournent 0, une erreur est générée et la variable système OK prend la valeur 0 (cf. ci-dessous).
- Après l’exécution de la commande, la variable aller contient une valeur indiquant si le lien aller spécifié est défini comme automatique :
0 = il n’y a pas de lien partant de champN. L’erreur de syntaxe n°16 (“Ce champ ne possède pas de lien”) est générée et la variable système OK prend la valeur 0.
1 = le statut automatique/manuel du lien aller spécifié est celui défini par l’option Lien aller auto dans les propriétés du lien en mode Développement (il n’a pas été modifié par programmation).
2 = le lien N vers 1 est manuel pour le process.
3 = le lien N vers 1 est automatique pour le process. - Après l’exécution de la commande, la variable retour contient une valeur indiquant si le lien retour spécifié est défini comme automatique :
0 = il n’y a pas de lien partant de champN. L’erreur de syntaxe n°16 (“Ce champ ne possède pas de lien”) est générée et la variable système OK prend la valeur 0.
1 = le statut automatique/manuel du lien retour spécifié est celui défini par l’option Lien retour auto dans les propriétés du lien en mode Développement (il n’a pas été modifié par programmation).
2 = le lien 1 vers N est manuel pour le process.
3 = le lien 1 vers N est automatique pour le process.
Vous pouvez comparer les valeurs reçues dans les paramètres aller et retour aux constantes du thème “Liens” :
| Constante | Type | Valeur |
| Automatique | Entier long | 3 |
| Configuration structure | Entier long | 1 |
| Manuel | Entier long | 2 |
| Pas de lien | Entier long | 0 |
Soit la structure suivante :
Les propriétés du lien reliant le champ [Employés]Société au champ [Sociétés]Nom sont les suivantes :
Le code ci-dessous illustre les différentes possibilités offertes par les commandes GET FIELD RELATION, GET AUTOMATIC RELATIONS et SET FIELD RELATION, SET AUTOMATIC RELATIONS ainsi que leurs effets :
GET AUTOMATIC RELATIONS(liens_Appel;liens_Retour) `retourne Faux, Faux
GET FIELD RELATION([Employés]Société;aller;retour) `retourne 1,1
GET FIELD RELATION([Employés]Société;aller;retour;*) `retourne 3,2
SET FIELD RELATION([Employés]Société;2;0) `passe le lien N vers 1 en manuel
GET FIELD RELATION([Employés]Société;aller;retour) `retourne 2,1
GET FIELD RELATION([Employés]Société;aller;retour;*) `retourne 2, 2
SET FIELD RELATION([Employés]Société;1;0) `rétablit les paramètres définis en
`structure pour le lien N vers 1
GET FIELD RELATION([Employés]Société;aller;retour) `retourne 1,1
GET FIELD RELATION([Employés]Société;aller;retour;*) `retourne 3,2
SET AUTOMATIC RELATIONS(True;True) `passe tous les liens de toutes les tables en automatique
GET AUTOMATIC RELATIONS(liens_Appel;liens_Retour) `retourne Vrai, Vrai
GET FIELD RELATION([Employés]Société;aller;retour) `retourne 1,1
GET FIELD RELATION([Employés]Société;aller;retour;*) `retourne 3,3
GET AUTOMATIC RELATIONS
GET RELATION PROPERTIES
SET AUTOMATIC RELATIONS
SET FIELD RELATION
Produit : 4D
Thème : Liens
Numéro :
920
Créé : 4D 2004
4D - Langage ( 4D v15.4)
4D - Langage ( 4D v15)
4D - Langage ( 4D v15.3)
