4D v15.4

QUERY BY ATTRIBUTE
  •  
 
Home
4D v15.4
4D Programmiersprache
Suchen
QUERY BY ATTRIBUTE

QUERY BY ATTRIBUTE 


 

QUERY BY ATTRIBUTE ( Tabellenname {; KonjOp}; ObjektFeld ; AttributPfad ; SuchOp ; Wert {; *} ) 
Parameter Typ   Beschreibung
Tabellenname  Tabelle in Tabelle, für die eine Auswahl Datensätze zurückgegeben werden soll
Ohne Angabe Haupttabelle
KonjOp  Operator in Verbindungsparameter bei mehrfacher Suche
ObjektFeld  Feld in Objektfeld zum Suchen von Attributen
AttributPfad  String in Name oder Pfad des Attributs
SuchOp  Operator, String in Suchoperator (Vergleichsoperator)
Wert  Text, Zahl, Datum, Zeit in Zu vergleichender Wert
*  Operator in Weiterer Suchbegriff folgt

QUERY BY ATTRIBUTE sucht nach Datensätzen, die zum Suchstring passen, definiert über die Parameter ObjektFeld, AttributPfad, SuchOp und Wert, und gibt eine Datensatzauswahl für Tabellenname zurück.

Hinweis: Weitere Informationen zu Objektfeldern (neu in 4D v15) finden Sie im Abschnitt Datenfeldtyp Objekt.

QUERY BY ATTRIBUTE ändert die aktuelle Auswahl von Tabellenname für den aktuellen Prozess und macht den ersten Datensatz der neuen Auswahl zum aktuellen Datensatz. Wird der Parameter Tabellenname weggelassen, gilt der Befehl für die Standardtabelle. Ist keine Standardtabelle vorhanden, tritt ein Fehler auf.

Der optionale Parameter KonjOp verbindet QUERY BY ATTRIBUTE Aufrufe in mehrfachen Suchen. Die logischen Operatoren sind dieselben wie im Befehl QUERY:

KonjunktionSymbol für QUERY BY ATTRIBUTE
UND&
ODER|
Außer#

Der Parameter KonjOp wird nicht bei einer einfachen Suche bzw. für den ersten Aufruf von QUERY BY ATTRIBUTE in einer mehrfachen Suche verwendet. Lassen Sie ihn in einer mehrfachen Suche weg, wird standardmäßig der Operator UND (&) verwendet.

In ObjektFeld übergeben Sie das Objektfeld, nach dessen Attribut(en) Sie suchen wollen. Gehört es zu einer Eine-Tabelle, definiert in Tabellenname mit einer automatischen oder manuellen Verknüpfung, kann ObjektFeld zu einer anderen Tabelle gehören.

In AttributPfad übergeben Sie den Namen oder Pfad des Attributs, dessen Werte Sie vergleichen wollen. Übergeben Sie ein einzelnes Attribut, z.B. "Alter", werden alle Attribute mit diesem Namen im Datensatz verglichen. Übergeben Sie einen Pfad, z.B. "Kinder.weiblich.Alter", werden nur dazu passende Attribute im Datensatz verglichen.
Ist ein Attribut "x" ein Array, sucht QUERY BY ATTRIBUTE nach Datensätzen mit einem Attribut "x", in dem mindestens ein Element zum Suchkriterium passt. Zur Suche in Array Attributen muss im Befehl QUERY BY ATTRIBUTE angegeben werden, dass Attribut "x" ein Array ist, d.h. an den Namen in AttributPfad wird ".[]" angefügt (siehe Beispiel 3).

Hinweise:

  • Beachten Sie, dass Attributnamen Groß- und Kleinschreibung berücksichtigen. Im gleichen Datensatz wird also zwischen dem Attributnamen "MeinAtt" und "meinAtt" unterschieden.
  • Mehrere Attributnamen werden zusammengezogen. Beispiel: " mein erstes Attribut .mein zweites Attribut " wird interpretiert als "mein erstes Attribut.mein zweites Attribut". 

Der Parameter SuchOp ist der Vergleichsoperator zwischen ObjektFeld und Wert. Sie können folgende Symbole übergeben:

VergleichSymbol für QUERY BY ATTRIBUTE
Ist gleich =
Ist ungleich #
Kleiner als <
Größer als >
Kleiner als oder gleich <=
Größer als oder gleich >=

Hinweis: Sie können den Vergleichsoperator auch in Textform angeben. Weitere Informationen dazu finden Sie unter dem Befehl QUERY.

Der Inhalt von Wert wird mit AttributPfad verglichen. Wert kann jeder Ausdruck sein, der denselben Datentyp wie AttributPfad bewertet. Er wird einmal zu Beginn der Suche bewertet und nicht für jeden Datensatz. Für eine Suche nach einem String innerhalb eines anderen (Suche mit "enthält") setzen Sie in Wert den Joker (@), um den gesuchten String zu isolieren, also z.B. "@Schmid@". In diesem Fall profitiert die Suche jedoch nur teilweise von dem Index (Kompaktheit der Datenspeicherung).

Die Struktur einer Suche nach Attribut lautet wie folgt:

 QUERY BY ATTRIBUTE([Tabellenname];[Tabellenname]ObjektFeld;"Attribut1.Attribut2";=;Wert)

Beachten Sie, dass immer davon ausgegangen wird, dass das Feld ein nicht-leeres Objekt mit festgelegten Attributen enthält. Nachfolgendes Beispiel gibt alle Datensätze zurück, in denen [Tabellenname]ObjektFeld ein Objekt mit einem Attribut Attribut1 enthält, das wiederum ein Objekt mit einem Attribut Attribut2 ist, dessen Wert ungleich Wert ist:

 QUERY BY ATTRIBUTE([Tabellenname];[Tabellenname]ObjektFeld;"Attribut1.Attribut2";#;Wert)

Deshalb gibt diese Suche nicht Objekte zurück, die weder Attribut1 noch Attribut2 enthalten.

Bei Objektfeldern wählt der Operator "#" Datensätze aus, für die kein Attribut des Feldes auf den angegebenen Wert zutrifft. Das bewertet 4D in diesem Kontext in ähnlicher Weise:

  • Felder, deren Wert des Attributs unterschiedlich ist vom angegebenen Wert
  • Felder, deren Wert des Attributs nicht vorhanden ist (oder einen Null Wert enthält)
Beispiel 1: Diese Suche gibt Datensätze mit den Personen zurück, die einen Hund haben, dessen Name nicht Rex ist und Datensätze von Personen, die keinen Hund oder einen Hund ohne Namen haben:
 QUERY BY ATTRIBUTE([People];[People]Animals;"dog.name";#;"Rex")

Beispiel 2: Diese Suche gibt Datensätze zurück, für die [Table]ObjectField ein Objekt mit einem Attribut Attribute1 enthält, das selbst ein Objekt mit einem Attribut attribute2 ist, dessen Wert ungleich value ist und Datensätze, deren Objektfelder nicht attribute1 oder attribute2 enthalten:
 QUERY BY ATTRIBUTE([Table] ;[Table]ObjectField ;"attribute1.attribute2";#;value)

Dieses Prinzip gilt auch bei Array Attributen.
Beispiel 3: Diese Suche gibt Datensätze der Personen zurück, die keine Adresse in Paris haben.
 QUERY BY ATTRIBUTE([People];[People]OB_Field;"locations[].city";#;"paris")

Für mehrfache Suchen nach Attributen gelten folgende Regeln:

  • Das erste Suchkriterium darf keinen Verknüpfungsoperator enthalten.
  • Jedes nachfolgende Kriterium kann mit einem Verknüpfungsoperator beginnen. Lassen Sie ihn weg, wird standardmäßig der Operator UND (&) verwendet.
  • Die einzelnen Suchaufrufe müssen den Parameter * verwenden. Der letzte Aufruf benötigt keinen *.
  • QUERY BY ATTRIBUTE kann mit QUERY Befehlen gemischt werden.
  • Um die Suche auszuführen, lassen Sie im letzten Aufruf von QUERY BY ATTRIBUTE den Parameter * weg. Als Alternative können Sie auch den Befehl QUERY nur mit der Tabelle ausführen, d.h. ohne die anderen Parameter (der Sucheditor erscheint nicht; an seiner Stelle wird die gerade definierte mehrfache Suche ausgeführt).

Hinweis: Jede Tabelle besitzt ihre eigenen aktuellen Suchläufe. Sie können also mehrere Suchläufe gleichzeitig anlegen, d.h. eine pro Tabelle. Für die eindeutige Zuordnung müssen Sie den Parameter Tabellenname angeben oder die Standardtabelle setzen.

Egal, auf welche Weise eine Suche definiert wurde, gilt folgendes:

  • Dauert die Ausführung der aktuellen Suchoperation etwas länger, zeigt 4D automatisch eine Meldung mit einem Ablaufbalken. Sie lässt sich über die Befehle MESSAGES ON und MESSAGES OFF ein- und ausschalten. Erscheint ein Ablaufbalken, kann der Benutzer bei Bedarf auf die Schaltfläche Stopp klicken, um die Suche zu unterbrechen. Ist die Suche abgeschlossen, wird OK auf 1 gesetzt; wird sie unterbrochen, wird OK auf 0 (Null) gesetzt.
  • Sind indizierte Objektfelder spezifiziert, wird die Suche, immer wenn möglich, optimiert (nach indizierten Feldern wird zuerst gesucht) und reduziert so den Zeitaufwand.

Datumsangaben werden in Objekten gemäß den Einstellungen der Datenbank gespeichert; standardmäßig wird die Zeitzone berücksichtigt (siehe Selector JSON use local time unter dem Befehl SET DATABASE PARAMETER). 

!1973-05-22! -> "1973-05-21T23:00:00.000Z"

Diese Einstellung wird auch beim Suchen berücksichtigt. Sie müssen sich nicht darum kümmern, wenn Sie Ihre Anwendung immer am gleichen Ort verwenden und die Einstellungen auf allen Rechnern, die auf die Daten zugreifen, gleich sind. Folgende Suche gibt dann z.B. Datensätze mit dem Attribut Geburtsdatum ist gleich !1973-05-22! (gesichert als "1973-05-21T23:00:00.00Z") korrekt zurück. Dieses Beispiel gilt für Deutschland GMT Winterzeit - 1 h: 22.Mai 1973 0:00 ist somit 21.Mai 1973 23:00:

 QUERY BY ATTRIBUTE([Persons];[Persons]OB_Info;"Geburtsdatum";=;!1973-05-22!)

Wollen Sie nicht die GMT Einstellungen verwenden, schreiben Sie folgende Anweisung:

 SET DATABASE PARAMETER(JSON use local time;0)

Beachten Sie, dass die Reichweite dieser Einstellung nur der Prozess ist. Führen Sie diese Anweisung aus, wird 1. Oktober 1965 auch als "1965-10-01T00:00:00.000Z" gespeichert. Sie müssen denselben Parameter jedoch vor dem Starten Ihrer Suchen setzen:

 SET DATABASE PARAMETER(JSON use local time;0)
 QUERY BY ATTRIBUTE([Persons];[Persons]OB_Info;"Geburtsdatum";=;!1976-11-27!)

In diesem Beispiel ist das Attribut "Alter" entweder ein String oder eine Ganzzahl. Wir wollen Personen im Alter 20 bis 29 finden. Die beiden ersten Zeilen suchen das Attribut als Ganzzahl (>=20 und < 30), die letzte Zeile sucht das Feld als String (startet mit "2", ist aber ungleich "2")

 QUERY BY ATTRIBUTE([Persons];[Persons]OB_Info;"Alter";>=;20;*)
 QUERY BY ATTRIBUTE([Persons]; & ;[Persons]OB_Info;"Alter";<;30;*)
 QUERY BY ATTRIBUTE([Persons];|;[Persons]OB_Info;"Alter";=;"2@";*)
 QUERY BY ATTRIBUTE([Persons]; & ;[Persons]OB_Info;"Alter";#;"2") // zuletzt kein * setzen, um die Ausführung zu starten

Mit dem Befehl QUERY BY ATTRIBUTE können Sie auch nach Datensätzen suchen, die bestimmte Attribute haben bzw. nicht haben. Dazu müssen Sie ein leeres Objekt verwenden:

  //Finde Datensätze, für die im Objektfeld email definiert ist
 C_OBJECT($undefined)
 QUERY BY ATTRIBUTE([Persons];[Persons]Info;"email";#;$undefined)

  //Finde Datensätze, für die im Objektfeld PLZ NICHT definiert ist
 C_OBJECT($undefined)
 QUERY BY ATTRIBUTE([Persons];[Persons]Info;"PLZ";=;$undefined)

Hinweis: Diese spezifische Syntax wird nicht in Attributen vom Typ Array unterstützt. Die Suche nach NULL Werten in Array Elementen liefert ein ungültiges Ergebnis.

Nach einem Feld mit Array Attributen suchen. Mit den beiden folgenden Datensätzen:

Datensatz 1:
[People]name: "martin"
[People]OB_Field:
    "locations" : [ {
                "kind":"office",
                "city":"paris"
            } ]

Datensatz 2:
[People]name: "smith"
[People]OB_Field:
    "locations" : [ {
                "kind":"home",
                "city":"lyon"
            } , {
                "kind":"office",
                "city":"paris"
            } ]

... findet QUERY BY ATTRIBUTE Personen mit einer Adresse in "paris". Dazu schreiben Sie folgende Anweisung:

  //Das Array Attribut mit der Syntax "[]"
 QUERY BY ATTRIBUTE([People];[People]OB_Field;"locations[].city";=;"paris")
  //wählt "martin" und "smith"

Hinweis: Haben Sie im selben Array Attribut mehrere Kriterien definiert, wird das passende Kriterium nicht zwingend auf dasselbe Array Element angewendet. Im folgenden Beispiel gibt die Suche "smith" zurück, weil es ein Element "locations" mit "kind" ist gleich "home" hat und ein Element "locations" mit "city" ist gleich "paris", selbst wenn es nicht dasselbe Element ist:

 QUERY BY ATTRIBUTE([People];[People]OB_Field;"locations[].kind";=;"home";*)
 QUERY BY ATTRIBUTE([People]; & ;[People]OB_Field;"locations[].city";=;"paris")
  //wählt "smith"



Siehe auch 

Struktur der 4D Programmiersprache Objekte

Vorige Seite
Nächste Seite