WR LIRE POSITION CURSEUR

4D Write v15


WR LIRE POSITION CURSEUR ( zone ; page ; colonne ; ligne ; position )

Paramètre	Type	Description
zone	Entier long	Zone 4D Write
page	Entier long	Numéro de la page où est le curseur
colonne	Entier long	Numéro de la colonne où est le curseur
ligne	Entier long	Numéro de la ligne dans la colonne
position	Entier long	Position horizontale du curseur dans la ligne

Description

La commande WR LIRE POSITION CURSEUR retourne la position du point d’insertion dans le document.

page
La valeur est comprise entre le premier et le dernier numéro de page du document. Le numéro de page tient compte du début de numérotation.
colonne
La valeur est comprise entre 1 et le nombre de colonnes.
ligne
La valeur est comprise entre 1 et le nombre de lignes de la colonne.
position
La valeur est comprise entre 1 et le nombre de caractères dans la ligne.

Si la sélection comporte plusieurs caractères, c'est la position de la première lettre qui est retournée. Vous pouvez revenir à cette position avec la commande WR FIXER POSITION CURSEUR en passant les mêmes paramètres.
Vous pouvez utiliser WR Lire cadre pour savoir dans quelle partie précise du document se trouve le curseur.

Exemple

Vous voulez permettre à un utilisateur d'insérer à tout moment votre logo en en-tête du document sans que cela ne modifie la saisie en cours. Pour cela, vous associez la méthode objet suivante à un bouton :

 C_ENTIER LONG($nCdre;$Colonne;$Ligne;$Pos)

 C_REEL($LargImage;$HautImage;$LargOrig;$HauteurOrig;$EntMargeHaut)

  `Dans quelle partie du document se trouve le curseur ?

 $nCdre:=WR Lire cadre(LaZone)

  `On récupère la position du curseur

 WR LIRE POSITION CURSEUR(LaZone;$Page;$Colonne;$Ligne;$Pos)

  `On se place dans l'en-tête du document

 WR FIXER CADRE(LaZone;wr entête droit)

  `On charge l'enregistrement dans lequel se trouve le logo à inclure dans l'en-tête

 TOUT SELECTIONNER([Interface])

  `Insertion du logo

 WR INSERER IMAGE(LaZone;[Interface]Logo;0)

  `Sélection du logo et lecture de sa taille

 WR SELECTIONNER(LaZone;4;1)

 WR LIRE TAILLE IMAGE(LaZone;$LargImage;$HautImage;$LargOrig;$HauteurOrig)

  `On descend le haut du texte pour retailler l'entête

 $EntMargeHaut:=WR Lire propriete document(LaZone;wr entête marge haut)

 WR FIXER PROPRIETE DOCUMENT(LaZone;wr texte marge haut;$EntMargeHaut+$HautImage)

  `On ajuste la hauteur de l'en-tête

 WR FIXER PROPRIETE DOCUMENT(LaZone;wr entête marge bas;$HautImage)

  `On se replace dans la partie du document ou l'on était au départ

 WR FIXER CADRE(LaZone;$nCdre)

  `On replace le curseur où il était au départ

 WR FIXER POSITION CURSEUR(LaZone;$Page;$Colonne;$Ligne;$Pos)

Voir aussi

WR FIXER POSITION CURSEUR
WR Lire cadre
WR LIRE COORDONNEES CURSEUR