4D View v15
PV FIXER CONTROLE CELLULE
- 4D View - Langage
-
- PV Valeur de cellule
-
- PV Valeur de cellule, Introduction
- PV AJOUTER CHAMPS DYNAMIQUES
- PV AJOUTER TAB DYNAMIQUES
- PV CELLULES VERS TABLEAU
- PV CHAMP VERS CELLULES
- PV EFFACER COL DYNAMIQUES
- PV ETAT MULTIPLE
- PV ETAT SIMPLE
- PV FIXER CHAMP CELLULE
- PV FIXER CONTROLE CELLULE
- PV FIXER FORMULE CELLULE
- PV FIXER VAL CELL DATE HEURE
- PV FIXER VALEUR CELL ALPHA
- PV FIXER VALEUR CELL BOOLEEN
- PV FIXER VALEUR CELL DATE
- PV FIXER VALEUR CELL HEURE
- PV FIXER VALEUR CELL IMAGE
- PV FIXER VALEUR CELL NOMBRE
- PV FIXER VALEUR CELL TEXTE
- PV FIXER VARIABLE CELLULE
- PV LIRE CHAMP CELLULE
- PV LIRE CONTROLE CELLULE
- PV Lire formule cellule
- PV Lire type valeur cellule
- PV LIRE VAL CELL DATE HEURE
- PV Lire valeur cell alpha
- PV Lire valeur cell booleen
- PV Lire valeur cell date
- PV Lire valeur cell heure
- PV Lire valeur cell image
- PV Lire valeur cell nombre
- PV Lire valeur cell texte
- PV Lire variable cellule
- PV LISTE CHAMPS VERS CELLULES
- PV MISE A JOUR ZONE DYNAMIQUE
- PV TABLEAU VERS CELLULES
PV FIXER CONTROLE CELLULE
| PV FIXER CONTROLE CELLULE ( zone ; colonne ; ligne ; type ; nomVar ; méthode ; titre ) | ||||||||
| Paramètre | Type | Description | ||||||
| zone | Entier long |
|
Zone 4D View | |||||
| colonne | Entier long |
|
Numéro de colonne de la cellule | |||||
| ligne | Entier long |
|
Numéro de ligne de la cellule | |||||
| type | Entier |
|
Type de contrôle | |||||
| nomVar | Chaîne |
|
Nom de la variable de gestion du contrôle | |||||
| méthode | Chaîne |
|
Nom de la méthode de rétro-appel | |||||
| titre | Chaîne |
|
Titre du contrôle | |||||
La commande PV FIXER CONTROLE CELLULE place un “contrôle” dans la cellule désignée par colonne et ligne.
Un contrôle est un objet de type bouton, case à cocher, bouton radio, liste déroulante ou combo box contenu dans une cellule. Si un contrôle existait déjà dans la cellule définie, il est remplacé par le nouveau, quel que soit son type.
type indique le type de contrôle (parmi les cinq ci-dessus) à placer dans la cellule. Pour définir ce paramètre, utilisez les constantes du thème PV Contrôles :
| Constante | Type | Valeur |
| pv contrôle aucun | Entier long | 0 |
| pv contrôle bouton | Entier long | 1 |
| pv contrôle bouton radio | Entier long | 2 |
| pv contrôle case à cocher | Entier long | 3 |
| pv contrôle combo box | Entier long | 5 |
| pv contrôle liste déroulante | Entier long | 4 |
nomVar est le nom de la variable associée au contrôle. Pour les contrôles de types liste déroulante ou combo box, passez le nom du tableau contenant les valeurs à afficher.
méthode contient le nom de la méthode de rétro-appel liée au contrôle. Pour plus d’informations sur le concept de rétro-appel, reportez-vous à la section PV Zone, Introduction.
titre contient le libellé du bouton, de la case à cocher, etc.
Les méthodes suivantes permettent de visualiser les différents types de contrôles.
- Bouton standard en C3 :
C_ENTIER LONG(vBoutonStandard) `Bouton standard
PV FIXER CONTROLE CELLULE(Zone;3;3;pv contrôle bouton;"vBoutonStandard";"RétroAppelBouton";"Bouton")
`Méthode RétroAppelBouton
C_ENTIER LONG($1) `Zone 4D View
C_ENTIER LONG($2) `N° de colonne
C_ENTIER LONG($3) `N° de ligne
C_POINTEUR($4) `Pointeur sur objet d'appel
ALERTE("Contrôle depuis la méthode : "+Nom methode courante)- Boutons radio en E3, E4, E5 :
C_ENTIER LONG(vRadio1;vRadio2;vRadio3) `Boutons radio
vRadio1:=1
vRadio2:=0
vRadio3:=0
PV FIXER CONTROLE CELLULE(Zone;5;3;pv contrôle bouton radio;"vRadio1";"RétroAppelRadio";"Jour")
PV FIXER CONTROLE CELLULE(Zone;5;4;pv contrôle bouton radio;"vRadio2";"RétroAppelRadio";"Mois")
PV FIXER CONTROLE CELLULE(Zone;5;5;pv contrôle bouton radio;"vRadio3";"RétroAppelRadio";"Année")
`Méthode RétroAppelRadio
C_ENTIER LONG($1) `Zone 4D View
C_ENTIER LONG($2) `N° de colonne
C_ENTIER LONG($3) `N° de ligne
C_POINTEUR($4) `Pointeur sur objet d'appel
C_TEXTE($Valeur)
Au cas ou
:($4=(->vRadio1))
vRadio2:=0
vRadio3:=0
$Valeur:="Jour"
:($4=(->vRadio2))
vRadio1:=0
vRadio3:=0
$Valeur:="Mois"
:($4=(->vRadio3))
vRadio1:=0
vRadio2:=0
$Valeur:="Année"
Fin de cas
PV FIXER VALEUR CELL TEXTE($1;($2+1);3;$Valeur)- Cases à cocher en E7, E8, E9 :
C_ENTIER LONG(vCac1;vCac2;vCac3) `Cases à cocher
vCac1:=0
vCac2:=0
vCac3:=0
PV FIXER CONTROLE CELLULE(Zone;5;7;pv contrôle case à cocher;"vCac1";"RétroAppelCac";"Initiation")
PV FIXER CONTROLE CELLULE(Zone;5;8;pv contrôle case à cocher;"vCac2";"RétroAppelCac";"Fondamentaux")
PV FIXER CONTROLE CELLULE(Zone;5;9;pv contrôle case à cocher;"vCac3";"RétroAppelCac";"Expert")
`Méthode RétroAppelCac
C_ENTIER LONG($1) `Zone 4D View
C_ENTIER LONG($2) `N° de colonne
C_ENTIER LONG($3) `N° de ligne
C_POINTEUR($4) `Pointeur sur objet d'appel
C_TEXTE($Valeur)
Si(vCac1=1)
$Valeur:="Initiation"
Fin de si
Si(vCac2=1)
Si($Valeur#"")
$Valeur:=$Valeur+" + "
Fin de si
$Valeur:=$Valeur+"Fondamentaux"
Fin de si
Si(vCac3=1)
Si($Valeur#"")
$Valeur:=$Valeur+" + "
Fin de si
$Valeur:=$Valeur+"Expert"
Fin de si
PV FIXER VALEUR CELL TEXTE($1;($2+1);7;$Valeur)- Liste déroulante en C5 :
TABLEAU TEXTE(TabListeDéroulante;5) `Pour liste déroulante
TabListeDéroulante{1}:="Lundi"
TabListeDéroulante{2}:="Mardi"
TabListeDéroulante{3}:="Mercredi"
TabListeDéroulante{4}:="Jeudi"
TabListeDéroulante{5}:="Vendredi"
TabListeDéroulante:=3 `Défaut à Mercredi
PV FIXER CONTROLE CELLULE(Zone;3;5;pv contrôle liste déroulante;"TabListeDéroulante";"RétroAppelListeDéroulante";"")
`Méthode RétroAppelListeDéroulante
C_ENTIER LONG($1) `Zone 4D View
C_ENTIER LONG($2) `N° de colonne
C_ENTIER LONG($3) `N° de ligne
C_POINTEUR($4) `Pointeur sur objet d'appel
PV FIXER VALEUR CELL TEXTE($1;3;6;TabListeDéroulante{TabListeDéroulante})- Combo box en C7 :
TABLEAU TEXTE(TabCombo;5) `Pour liste de la combo Box
TabCombo{1}:="Lundi"
TabCombo{2}:="Mardi"
TabCombo{3}:="Mercredi"
TabCombo{4}:="Jeudi"
TabCombo{5}:="Vendredi"
TabCombo:=5 `Défaut à Vendredi
PV FIXER CONTROLE CELLULE(Zone;3;7;pv contrôle combo box;"TabCombo";"RétroAppelCombo";"")
`Méthode : RétroAppelCombo
C_ENTIER LONG($1) `Zone 4D View
C_ENTIER LONG($2) `N° de colonne
C_ENTIER LONG($3) `N° de ligne
C_POINTEUR($4) `Pointeur sur objet d'appel
PV FIXER VALEUR CELL TEXTE($1;3;8;TabCombo{0})
Produit : 4D View
Thème : PV Valeur de cellule
Numéro :
15916
Nom intl. : PV SET CELL CONTROL
Créé : 4D View 6.8
4D View - Langage ( 4D View v15)
