4D View v15
PV Color to index
PV Color to index
| PV Color to index ( cor ) -> Resultado | ||||||||
| Parâmetro | Tipo | Descrição | ||||||
| cor | Inteiro longo |
|
Número da cor | |||||
| Resultado | Inteiro |
|
Número de cor indexado | |||||
O comando PV Color to index devolve o número da cor RGB especificado na paleta 4D por padrão. As cores indexadas 4D vão de 0 a 255.
Consulte as descrições dos seguintes comandos 4D para obter informação detalhada sobre as cores RGB utilizadas por 4D:
- OBJECT SET RGB COLORS para o sistema de cores RGB utilizado por 4D.
- OBJECT SET COLOR para a paleta 4D de cores indexadas.
Nota: o código interno de cores de 4D View é do tipo RGB, que se reversa com respeito ao código RGB de 4D; no embargo, os princípios de uso são idênticos.
Este método estabelece na célula A1 a cor de fundo definido pelos valores RGB (0 a 255) introduzido nas células A2, A3 e A4. A célula C1 mostra o número de cor indexado mais perto na paleta 4D, com a cor de fundo ad hoc, enquanto as células C2, C3, C4 mostram os valores RGB correspondentes a esta cor indexada, permitindo visualizar a diferença entre os valores iniciais.
C_LONGINT($Color) //Cor de fundo da célula A1 (RGB) depois cor de indexação
C_LONGINT($Red;$Green;$Blue) //cores RGB ao início e quando terminar
C_LONGINT($Index) //Número na paleta 4D
PV SET CELL STRING VALUE(Area;2;1;"Color") //Etiquetas
PV SET CELL STRING VALUE(Area;2;2;"Red")
PV SET CELL STRING VALUE(Area;2;3;"Green")
PV SET CELL STRING VALUE(Area;2;4;"Blue")
$Red:=PV Get cell num value(Area;1;2) //Cores RGB iniciais
$Green:=PV Get cell num value(Area;1;3)
$Blue:=PV Get cell num value(Area;1;4)
$Color:=PV RGB to color($Red;$Green;$Blue)
PV SET CELL PROPERTY(Area;1;1;pv style color back odd;$Color) //Atribui fundo A1
$Index:=PV Color to index($Color) //"Indexando"
PV SET CELL NUM VALUE(Area;3;1;$Index) //Número na paleta 4D
$Color:=PV Index to color($Index) //Nova Cor
PV SET CELL PROPERTY(Area;3;1;pv style color back odd;$Color) //Atribui fundo C1
PV COLOR TO RGB($Color;$Red;$Green;$Blue) //Decompõe
PV SET CELL NUM VALUE(Area;3;2;$Red) //cores RGB depois de "indexar"
PV SET CELL NUM VALUE(Area;3;3;$Green)
PV SET CELL NUM VALUE(Area;3;4;$Blue)
Produto: 4D View
Tema: PV Utilitários
Número
15861
Criado por: 4D View 6.8
4D View Linguagem ( 4D View v15)
