4D v13
PV Get row height
PV Get row height
| PV Get row height ( area ; linea ) -> resultado | ||||||||
| Parámetro | Tipo | Descripción | ||||||
| area | Entero largo |
|
Área 4D View | |||||
| linea | Entero largo |
|
Número de línea | |||||
| resultado | Entero |
|
Altura de la línea | |||||
El comando PV Get row height devuelve la altura en píxeles de la linea especificada.
Consulte el ejemplo del comando PV SET COLUMNS WIDTH.
Desde la versión 2004.5 de 4D, el comando Print form permite imprimir áreas 4D View. Generalmente, estas áreas se imprimen con una altura fija. El siguiente ejemplo muestra cómo utilizar los comandos de impresión de 4D y el comando PV Get row height para variar la altura de impresión del área 4D View en función de su contenido.
- Este es el método de formulario llamado por el comando Print form:
If(Form event=On Printing Detail)
GET OBJECT RECT(4DViewarea;$left;$top;$right;$bottom)
$posmarker:=Get print marker(Form Detail)
$areaheight:=$bottom-$top
$newheight:=4DViewSizeCalcul
`4DViewSizeCalcul devuelve la altura del área 4D View dependiendo de su contenido
`Este método se muestra a continuación
$offset:=$newheight-$areaheight
MOVE OBJECT(4DViewarea;0;0;0;$offset)
SET PRINT MARKER(Form Detail;$posmarker+$offset)
End if- El método 4DViewSizeCalcul es el siguiente:
$area:=PV New offscreen area
PV BLOB TO AREA($area;[Table 1]View_)
PV EXECUTE COMMAND($area;pv cmd edit go to last cell)
PV GET CURRENT CELL($area;$column;$row)
$height:=0
For($i;1;$row)
$rowHeight:=PV Get row height($area;$i)
$height:=$height+$rowHeight
End for
PV DELETE OFFSCREEN AREA($area)
$0:=Trunc($height*0.75;0)
Producto: 4D
Tema: PV Columnas y líneas
Número
15951
Lista alfabética de los comandos
Modificado: 4D View 2004.5
PV Get column width
PV SET ROWS HEIGHT
