4D Doc Center : String

4D v12.4


String ( expressao {; formato {; adTempo}} ) -> Resultado

Parâmetro	Tipo	Descrição
expressao	Expression	Expressão para qual vai retornar o formato string (pode ser um Real, Inteiro, Inteiro longo, Data, string hora, texto ou booleano)
formato	cadeia, Inteiro longo	Formato exibiçao
adTempo	Hora	Tempo a adicionar se a expressão for uma data
Resultado	cadeia	Formato string da expressão

Descrição

O comando String devolve em forma de string alfanumérica a expressão de tipo numérico, Data, Hora, string ou Booleana que se passa em expressão.

Se não passar o parâmetro opcional formato, a string é devolvvida no formato como padrão do tipo de dados correspondente. Se passa formato, pode definir o formato da string resultante.

O parâmetro opcional adHora adiciona uma hora a uma data em um formato combinado. Apenas pode ser utilizado quando o parâmetro expressão for uma data (ver abaixo).

Expressões numéricas

Se expressão for uma expressão numérica (Real, Inteiro, Inteiro longo), pode passar o formato da string opcional. Estes são alguns exemplos:

Exemplo	Resultado
String(2^15) ` Utilizar formato padrão	32768 (formato padrão)
String(2^15;"###,##0 habitantes")	32,768 habitantes
String(1/3;"##0.00000")	0.33333
String(1/3) ` Utilizar formato por defecto	0.3333333333333333 (formato padrão)
String(Arctan(1)*4)	3.1415926535897931 (formato padrão)
String(Arctan(1)*4;"##0.00")	3.14
String(-1;"&x")	0xFFFFFFFF
String(-1;"&$")	$FFFFFFFF
String(0 ?+ 7;"&x")	0x80
String(0 ?+ 7;"&$")	$80
String(0 ?+ 14;"&x")	0x4000
String(0 ?+ 14;"&$")	$4000
String(50,3;"&xml")	50.3
String(Num(1=1);"True;;False")	True
String(Num(1=2);"True;;False")	False

O formato é especificado da mesma forma que para um campo numérico em um formulário. Para maior informação sobre formatos numéricos, consulte a seção Formatos de saída do manual de Desenho de 4D. Igualmente pode passar o nome de um estilo personalizado em formato. O nome do estilo personalizado deve estar precedido pelo caractere “|”.

Expressões de tipo Data

Se expressão for de tipo Data, a string é devolvida no formato como padrão definido no sistema.
No parâmetro formato, pode passar uma das constantes descritas abaixo (tema Formatos de saída de datas):

Neste caso, também pode passar uma hora no parâmetro adHora. Este parâmetro lhe permite combinar uma data e uma hora com o objetivo de gerar marcadores de tempo de acordo com as normas em vigor (constantes ISO Date, ISO Date GMT e Date RFC 1123). Estes formatos são particularmente úteis no contexto dos processos XML e Web. O parâmetro adHora apenas é utilizado quando o parâmetro expressão for uma data.

Constante	Tipo	Valor	Comentário
Blank if null date	Inteiro longo	100	"" ao invés de 0
Date RFC 1123	Inteiro longo	10
Internal date abbreviated	Inteiro longo	6
Internal date long	Inteiro longo	5
Internal date short	Inteiro longo	7
Internal date short special	Inteiro longo	4
ISO Date	Inteiro longo	8
ISO Date GMT	Inteiro longo	9
System date abbreviated	Inteiro longo	2
System date long	Inteiro longo	3
System date short	Inteiro longo	1

Estes são alguns exemplos de formatos simples (asumindo que a data atual é 29/12/2009):

 $vsResult:=String(Current date) ` $vsResult assume o valor "29/12/09"

 $vsResult:=String(Current date;Internal date long) ` $vsResult assume o valor "29 de dezembro de 2009"

 $vsResult:=String(Current date;ISO Date) ` $vsResult assume o valor "2009-12-29T00:00:00"

Notas para os formatos combinados data/hora:

O formatoISO Date corresponde à norma ISO8601. Este formato contém uma data e uma hora. Por exemplo, a data de 31 de maio de 2006 à 1:20 p.m. se escreve 2006-05-31T13:20:00. Se não passar o parâmetro adHOra, a parte hora é preenchida com 0 (ver exemplo). Este formato expressa a data e hora local.
$minhadata:=String(Current date;ISO Date) // devolve por exemplo 2010-09-13T00:00:00 $minhadata:=String(Current date;ISO Date;Current time) // devolve 2010-09-13T18:11:53
O formato ISO Date GMT é similar ao formato ISO Date, exceto que expressa a data e a hora com relação a zona do fuso horário (hora GMT).
$minhadata:=String(Current date;ISO Date GMT;Current time) // retorna 2010-09-13T16:11:53Z

Note que o caractere "Z" ao final indica o formato GMT.
Se apenas passa uma data, o comando devolve a data à meia noite (hora local) expressa em hora GMT o qual pode fazer com que a data se mova para frente ou para trás, dependendo da zona horária local:
O formato Date RFC 1123 permite formatar um conjunto data/hora seguindo a norma definida pelos RFC 822 e 1123. Este formato é necessário, por exemplo, para fixar a data de vencimento das cookies em um cabeçalho HTTP.
$minhadata:=String(Current date;Date RFC 1123;Current time) //devolve, por exemplo Fri, 10 Sep 2010 13:07:20 GMT

A hora expressa considera a hora do fuso horário (zona GMT). Se passar uma data, o comando retorna a data com a hora da meia noite (hora loca) expressa em hora GMT o qual pode fazer com que a data se mova para frente ou para trás, dependendo da zona horária local:
$minhadata:=String(Current date;Date RFC 1123) // devolve Thu, 09 Sep 2010 22:00:00 GMT

Expressões de tipo Hora

Se expressão for do tipo Hora, a string é devolvida utilizando o formato como padrão HH:MM:SS. Pode passar no parâmetro formato uma das seguintes constantes do tema "Time Display Formats"):

Constante	Tipo	Valor
Blank if null time	Inteiro longo	100
HH MM	Inteiro longo	2
HH MM AM PM	Inteiro longo	5
HH MM SS	Inteiro longo	1
Hour Min	Inteiro longo	4
Hour Min Sec	Inteiro longo	3
ISO Time	Inteiro longo	8
Min Sec	Inteiro longo	7
MM SS	Inteiro longo	6
System time long	Inteiro longo	11
System time long abbreviated	Inteiro longo	10
System time short	Inteiro longo	9

Notas:

O formato ISO Date Time corresponde à norma ISO8601. Este formato contém uma data e uma hora. Por exemplo, a data de 31 de maio de 2006 à 1:20 p.m. é escrita 2006-05-31T13:20:00. Isso se utiliza para os processos XML e com serviços Web. 4D não permite armazenar uma data e hora em um campo apenas. Entretanto, é posible administrar as datas neste formato utilizando o comando String
A constante Blank if null deve ser adicionada ao formato; indica que em caso de um valor nulo 4D deve devolver uma string vazia ao invés de zeros.

Estes exemplos assumem que a hora atual 5:30 PM e 45 segundos:

 $vsResult:=String(Current time) ` $vsResult toma o valor "17:30:45"

 $vsResult:=String(Current time;Hour Min Sec) ` $vsResult toma o valor "17 horas 30 minutos 45 segundos"

Expressões de tipo string

Se expressão for de tipo Alfa ou Texto, o comando devolve o mesmo valor que se passa no parâmetro. Isso pode ser útil particularmente em programação genérica utilizando ponteiros.
Neste caso, se for passado, o parâmetro formato será ignorado.

Expressões de tipo Booleano

Se expressão for de tipo Booleano, o comando devolve a string “True” ou “False” na linguagem da aplicação (por exemplo, “Vrai” ou “Faux” em uma versão francesa de 4D).

Neste caso se for passado, o parâmetro formato será ignorado.