4D v12.1
Joins
- Manual de SQL
-
- Tutorial
-
- Introdução
- Receber o resultado de um pedido SQL em uma variável
- Utilizar a cláusula WHERE
- Receber o resultado de um pedido SQL em um array
- Utilizar CAST
- Utilizar a cláusula ORDER BY
- Utilizar a cláusula GROUP BY
- Utilizar funçõs estadísticas
- Utilizar a cláusula HAVING
- Chamar os métodos 4D desde o código SQL
- Joins
- Utilizar Alias
- Subconsultas
- Seguimento e depuração do código SQL
- Data Definition Language
- Conexões Externas
- Conexão ao motor SQL 4D via o driver ODBC
4D v12.1
Joins
Joins
Agora queremos conhecer a cidade de nascimento de cada ator. A lista de atores está na tabela ACTORS e a lista de cidades na tabela CITIES. Para executar esta pesquisa necessitamos unir as duas tabelas: ACTORS e CITIES.
- O código 4D inicial seria:
ARRAY LONGINT(aSoldTickets;0)
ARRAY TEXT(aTitles;0)
ARRAY TEXT(aDirectors;0)
C_LONGINT($i;$vInd)
$vInd:=0
ALL RECORDS([ACTORS])
For($i;1;Records in selection([ACTORS]))
$vInd:=$vInd+1
INSERT IN ARRAY(aTitles;$vInd;1)
aTitles{$vInd}:=[ACTORS]FirstName+" "+[ACTORS]LastName
RELATE ONE([ACTORS]Birth_City_ID)
INSERT IN ARRAY(aDirectors;$vInd;1)
aDirectors{$vInd}:=[CITIES]City_Name
NEXT RECORD([ACTORS])
End for
` Inicia o resto das colunas do list box para mostrar a informação
ARRAY INTEGER(aMovieYear;Size of array(aTitles))
ARRAY TEXT(aMedias;Size of array(aTitles))
ARRAY LONGINT(aSoldTickets;Size of array(aTitles))
ARRAY LONGINT(aNrActors;Size of array(aTitles))
MULTI SORT ARRAY(aDirectors;>;aTitles;>;aMovieYear;aMedias;aSoldTickets;aNrActors)
- Utilizando código SQL:
ARRAY TEXT(aTitles;0)
ARRAY TEXT(aDirectors;0)
Begin SQL
SELECT CONCAT(CONCAT(ACTORS.FirstName,' '),ACTORS.LastName), CITIES.City_Name
FROM ACTORS, CITIES
WHERE ACTORS.Birth_City_ID=CITIES.City_ID
ORDER BY 2,1
INTO :aTitles, :aDirectors;
End SQL
` Inicia o resto das colunas do list box para mostrar a informação
ARRAY INTEGER(aMovieYear;Size of array(aTitles))
ARRAY TEXT(aMedias;Size of array(aTitles))
ARRAY LONGINT(aSoldTickets;Size of array(aTitles))
ARRAY LONGINT(aNrActors;Size of array(aTitles))
- Utilizando comandos SQL genéricos:
ARRAY TEXT(aTitles;0)
ARRAY TEXT(aDirectors;0)
C_TEXT($tQueryTxt)
SQL LOGIN(SQL_INTERNAL;"";"")
$tQueryTxt:=""
$tQueryTxt:=$tQueryTxt+"SELECT CONCAT(CONCAT(ACTORS.FirstName,' '),ACTORS.LastName), CITIES.City_Name"
$tQueryTxt:=$tQueryTxt+" FROM ACTORS, CITIES"
$tQueryTxt:=$tQueryTxt+" WHERE ACTORS.Birth_City_ID=CITIES.City_ID"
$tQueryTxt:=$tQueryTxt+" ORDER BY 2,1"
SQL EXECUTE($tQueryTxt;aTitles;aDirectors)
SQL LOAD RECORD(SQL All Records)
SQL LOGOUT
` Inicia o resto das colunas do list box para mostrar a informação
ARRAY INTEGER(aMovieYear;Size of array(aTitles))
ARRAY TEXT(aMedias;Size of array(aTitles))
ARRAY LONGINT(aSoldTickets;Size of array(aTitles))
ARRAY LONGINT(aNrActors;Size of array(aTitles))
- Utilizando o comando QUERY BY SQL, não podemos realizar a pesquisa anterior porque não é possível passar mais de uma tabela como primeiro parâmetro.
- Utilizando o comando SQL EXECUTE IMMEDIATE:
ARRAY TEXT(aTitles;0)
ARRAY TEXT(aDirectors;0)
C_TEXT($tQueryTxt)
$tQueryTxt:=""
$tQueryTxt:=$tQueryTxt+"SELECT CONCAT(CONCAT(ACTORS.FirstName,' '),ACTORS.LastName), CITIES.City_Name"
$tQueryTxt:=$tQueryTxt+" FROM ACTORS, CITIES"
$tQueryTxt:=$tQueryTxt+" WHERE ACTORS.Birth_City_ID=CITIES.City_ID"
$tQueryTxt:=$tQueryTxt+" ORDER BY 2,1"
$tQueryTxt:=$tQueryTxt+" INTO :aTitles, :aDirectors"
Begin SQL
EXECUTE IMMEDIATE :$tQueryTxt;
End SQL
` Inicia o resto das colunas do list box para mostrar a informação
ARRAY INTEGER(aMovieYear;Size of array(aTitles))
ARRAY TEXT(aMedias;Size of array(aTitles))
ARRAY LONGINT(aSoldTickets;Size of array(aTitles))
ARRAY LONGINT(aNrActors;Size of array(aTitles))
PROPRIEDADES
Produto: 4D
Tema: Tutorial
© 4D SAS 1985 - 2012. Todos os direitos reservados.