WR GET CURSOR POSITION

4D Write v16


WR GET CURSOR POSITION ( area ; pag ; columna ; grueso ; posicion )

Parámetro	Tipo	Descripción
area	Entero largo	Área 4D Write
pag	Entero largo	Número de la página donde está el cursor
columna	Entero largo	Número de la columna donde está el cursor
grueso	Entero largo	Número de la línea en la columna
posicion	Entero largo	Posición horizontal del cursor en la línea

Descripción

El comando WR GET CURSOR POSITION devuelve la posición del punto de inserción en el documento.

pagina: el valor debe estar entre el primero y el último número de página del documento. Estos números tienen en cuenta la numeración de página personalizada, si la hay.
columna: este valor está entre 1 y el número total de columnas.
linea: este valor está entre el 1 y el número total de líneas de la columna.
posicion: este valor debe estar entre 1 y el número total de caracteres en la línea.

Si la selección contiene varios caracteres, se devuelve la posición del primer carácter.
Más tarde, puede volver a esta posición, utilizando el comando WR SET CURSOR POSITION con los mismos parámetros.
Puede utilizar WR Get frame para determinar en qué área está el cursor.

Ejemplo

Usted quiere permitir al usuario insertar un logo en el encabezado del documento, sin perder la posición actual del cursor en el texto. Para hacer esto, asocie el siguiente método al botón de inserción:

 C_LONGINT($frame;$Col;$Line;$Pos)

 C_REAL($PictWidth;$PictHeight;$OrigWidth;$OrigHeight;$HeadTopMargin)

  `En qué parte del documento se encuentra el cursor?

 $frame:=WR Get frame(Area)

  `Recuperamos la posición actual del cursor

 WR GET CURSOR POSITION(Area;$Page;$Col;$Line;$Pos)

  `Pasamos el área actual al encabezado del documento

 WR SET FRAME(Area;wr right header)

  `Cargamos el registro que contiene el logo a incluir

 ALL RECORDS([Interface])

  `Inserción del logo

 WR INSERT PICTURE(Area;[Interface]Logo;0)

  `Selección del logo y lectura de su tamaño

 WR SELECT(Area;4;1)

 WR GET PICTURE SIZE(Area;$PictWidth;$PictHeight;$OrigWidth;$OrigHeight)

  `Se ajusta la altura del encabezado a la imagen

 $HeadTopMargin:=WR Get doc property(Area;wr header top margin)

 WR SET DOC PROPERTY(Area;wr text top margin;$HeadTopMargin+$PictHeight)

 WR SET DOC PROPERTY(Area;wr header bottom margin;$PictHeight)

  `Volvemos al marco donde estaba el cursor

 WR SET FRAME(Area;$frame)

  `El cursor vuelve a su posición original

 WR SET CURSOR POSITION(Area;$Page;$Col;$Line;$Pos)

Ver también

WR GET CURSOR COORDINATES
WR Get frame
WR SET CURSOR POSITION