4D View v16

PV SET STYLE PROPERTY

Accueil

 
Accueil
4D View v16
4D View - Langage
PV Style
PV SET STYLE PROPERTY

PV SET STYLE PROPERTY 


 

PV SET STYLE PROPERTY ( zone ; style ; propriété ; valeur ) 
Paramètre Type   Description
zone  Entier long in Zone 4D View
style  Entier long in Numéro de la feuille de style
propriété  Entier long in Numéro de la propriété
valeur  Entier long in Valeur de la propriété

La commande PV FIXER PROPRIETE STYLE fixe la valeur de propriété pour la feuille de style dont le numéro est style.

Utilisez les constantes du thème PV Propriétés style pour définir le paramètre propriété et les constantes du thème PV Valeurs style pour définir le paramètre valeur. Le choix de la constante à affecter au paramètre valeur dépend de la propriété choisie.

Constante Type Valeur Comment
pv style automatic word wrap Entier long 33 Permet d’activer la fonction provoquant le retour à la ligne automatique du contenu d’une cellule lorsqu’il excède la largeur de la cellule. Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur vrai : le contenu de la cellule passe automatiquement à la ligne si nécessaire.
  • pv valeur faux : le contenu de la cellule déborde sur les cellules adjacentes si nécessaire.
pv style based on Entier long 4 La cellule utilise comme modèle la feuille de style dont le numéro est passé dans le paramètre valeur. Valeurs associées : numéros de feuilles de style ou constantes du thème PV Style valeurs spéciales.
pv style color back even Entier long 11 Permet de fixer la couleur de fond de la cellule si elle est située sur une ligne paire. Valeurs associées : numéros de couleurs (reportez-vous aux commandes PV RVB vers couleur et PV Index vers couleur) ou pv valeur aucune (thème PV Valeurs style) pour n’associer aucune couleur.
pv style color back odd Entier long 12 Permet de fixer la couleur de fond de la cellule si elle est située sur une ligne impaire. Valeurs associées : numéros de couleurs (reportez-vous aux commandes PV RVB vers couleur et PV Index vers couleur) ou pv valeur aucune (thème PV Valeurs style) pour n’associer aucune couleur.
pv style color minus even Entier long 17 Permet de fixer la couleur du texte contenu dans la cellule si elle est située sur une ligne paire et sa valeur est négative. Valeurs associées : numéros de couleurs (reportez-vous aux commandes PV RVB vers couleur et PV Index vers couleur).
pv style color minus odd Entier long 18 Permet de fixer la couleur du texte contenu dans la cellule si elle est située sur une ligne impaire et sa valeur est négative. Valeurs associées : numéros de couleurs (reportez-vous aux commandes PV RVB vers couleur et PV Index vers couleur).
pv style color text even Entier long 13 Permet de fixer la couleur du texte contenu dans la cellule si elle est située sur une ligne paire. Valeurs associées : numéros de couleurs (reportez-vous aux commandes PV RVB vers couleur et PV Index vers couleur).
pv style color text odd Entier long 14 Permet de fixer la couleur du texte contenu dans la cellule si elle est située sur une ligne impaire. Valeurs associées : numéros de couleurs (reportez-vous aux commandes PV RVB vers couleur et PV Index vers couleur).
pv style color zero even Entier long 15 Permet de fixer la couleur du texte contenu dans la cellule si elle est située sur une ligne paire et sa valeur est 0 (zéro). Valeurs associées : numéros de couleurs (reportez-vous aux commandes PV RVB vers couleur et PV Index vers couleur).
pv style color zero odd Entier long 16 Permet de fixer la couleur du texte contenu dans la cellule si elle est située sur une ligne impaire. Valeurs associées : numéros de couleurs (reportez-vous aux commandes PV RVB vers couleur et PV Index vers couleur).
pv style format alpha Entier long 6 La cellule utilise le format d’affichage de texte dont le numéro est passé dans le paramètre valeur. Valeurs associées : numéros de formats d'affichage.
pv style format bool Entier long 8 La cellule utilise le format d’affichage booléen dont le numéro est passé dans le paramètre valeur. Valeurs associées : numéros de formats d'affichage.
pv style format date time Entier long 9 La cellule utilise le format d’affichage date et heure dont le numéro est passé dans le paramètre valeur. Valeurs associées : constantes du thème PV Style format date heure.
  • pv Format court : 21/02/02
  • pv Format abrégé : jeu 21 fév 2002
  • pv Format long : jeudi 21 février 2002
  • pv Format spécial : 21/02/2002
  • pv Jour Mois Année : 21 février, 2002
  • pv Abrégé Jour Mois Année : 21 fév, 2002
  • pv Jour de la semaine : jeudi
  • pv Jour du mois : 21
  • pv Mois : février
  • pv Mois de année : 2
  • pv Année : 2002
  • pv Long à h mn AM PM : jeudi 21 février 2002 à 12:30 PM
  • pv Abrégé à h mn AM PM : jeu 21 fév 2002 à 12:30 PM
  • pv Court à H MN SEC : 21/02/02 à 12:30:00
  • pv Jour Mois An à H MN AM PM : 21 février, 2002 à 12:30 PM
  • pv Spécial et H MN SEC : 21/02/2002 et 12 heures 30 minutes 0 seconde
  • pv h mn sec : 12:30:00
  • pv h mn : 12:30
  • pv Heure Minute Seconde : 12 heures 30 minutes 0 secondes
  • pv Heure Minute : 12 heures 30 minutes
  • pv h mn AM PM : 12:30 PM

Note : Le résultat obtenu peut varier en fonction des réglages système.
pv style format forced text Entier long 32 Permet de forcer l'affichage de la cellule en texte brut, c'est-à-dire sans le formatage effectué par 4D View en fonction de son contenu (nombre, date, texte, etc.). Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur vrai : le contenu de la cellule est affiché sans formatage.
  • pv valeur faux (valeur par défaut) : la cellule est affichée avec formatage automatique en fonction de son contenu.
pv style format num Entier long 7 La cellule utilise le format d’affichage numérique dont le numéro est passé dans le paramètre valeur. Valeurs associées : numéros de formats d'affichage.

Note : Les numéros des formats d'affichage par défaut correspondent à leur position dans le menu de sélection de format (boîte de dialogue “Formats” de cellules).
pv style format picture Entier long 10 Permet de définir le format d'affichage de l'image liée à la cellule. Valeurs associées : constantes du thème PV Affichage image.
  • pv image tronquée non centrée
  • pv image tronquée centrée
  • pv image mosaïque
  • pv image proportionnelle
  • pv image non tronquée
  • pv image prop centrée
pv style hidden Entier long 1 Permet de fixer le verrouillage et de cacher le contenu de la cellule. Le contenu d'une cellule cachée n'apparaît pas et ne peut plus être sélectionné, modifié, etc. Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur vrai : verrouille et cache la cellule.
  • pv valeur faux : la cellule n'est ni verrouillée ni cachée.
pv style hor alignment Entier long 29 Permet de fixer l'alignement horizontal du contenu de la cellule. Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur align hor défaut : applique l'alignement horizontal par défaut à la cellule.
  • pv valeur align hor gauche : applique un alignement horizontal à gauche à la cellule.
  • pv valeur align hor centré : applique un alignement horizontal centré à la cellule.
  • pv valeur align hor droit : applique un alignement horizontal à droite à la cellule.
pv style locked Entier long 0 Permet de fixer le verrouillage pour l'utilisateur de la cellule. Le contenu d'une cellule verrouillée ne peut plus être sélectionné, modifié, etc. Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur vrai : verrouille la cellule.
  • pv valeur faux : la cellule n'est pas verrouillée.
pv style rotation Entier long 31 Permet de fixer la rotation du contenu de la cellule. Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur rotation 0 : n'applique pas de rotation à la cellule.
  • pv valeur rotation 90 : applique une rotation de 90° vers la gauche à la cellule.
  • pv valeur rotation 180 : applique une rotation de 180° à la cellule.
  • pv valeur rotation 270 : applique une rotation de 270° vers la gauche à la cellule.
pv style spellcheck Entier long 2 Permet d’appliquer une correction orthographique sur la cellule. Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur vrai : une correction othographique est appliquée à la cellule.
  • pv valeur faux : aucune correction othographique n'est appliquée à la cellule.
pv style text bold Entier long 22 Permet de fixer l'attribut 'Gras' du texte de la cellule. Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur vrai : applique l'attribut 'Gras' à la cellule.
  • pv valeur faux : n'applique pas l'attribut 'Gras' à la cellule.
pv style text condensed Entier long 27 Permet de fixer l'attribut 'Condensé' du texte de la cellule. Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur vrai : applique l'attribut 'Condensé' à la cellule.
  • pv valeur faux : n'applique pas l'attribut 'Condensé' à la cellule.
pv style text extended Entier long 28 Permet de fixer l'attribut 'Etendu' du texte de la cellule. Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur vrai : applique l'attribut 'Etendu' à la cellule.
  • pv valeur faux : n'applique pas l'attribut 'Etendu' à la cellule.
pv style text face Entier long 21 Permet de fixer la feuille de style de la cellule. Valeurs associées : numéros de feuilles de style ou constantes du thème PV Style valeurs spéciales.
pv style text font Entier long 19 Permet de fixer la police de la cellule. Valeurs associées : numéros de polices (reportez-vous aux commandes PV Ajouter police et PV LIRE LISTE POLICES).
pv style text italic Entier long 23 Permet de fixer l'attribut 'Italique' du texte de la cellule. Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur vrai : applique l'attribut 'Italique' à la cellule.
  • pv valeur faux : n'applique pas l'attribut 'Italique' à la cellule.
pv style text outline Entier long 25 Permet de fixer l'attribut 'Relief' du texte de la cellule. Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur vrai : applique l'attribut 'Relief' à la cellule.
  • pv valeur faux : n'applique pas l'attribut 'Relief' à la cellule.
pv style text shadow Entier long 26 Permet de fixer l'attribut 'Ombré' du texte de la cellule. Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur vrai : applique l'attribut 'Ombré' à la cellule.
  • pv valeur faux : n'applique pas l'attribut 'Ombré' à la cellule.
pv style text size Entier long 20 Permet de fixer la taille de police de la cellule. Valeurs associées : tailles en pixels.
pv style text underline Entier long 24 Permet de fixer l'attribut 'Souligné' du texte de la cellule. Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur vrai : applique l'attribut 'Souligné' à la cellule.
  • pv valeur faux : n'applique pas l'attribut 'Souligné' à la cellule.
pv style use picture height Entier long 3 Permet d’adapter la taille de la cellule en fonction de la taille de l’image qui lui est liée. Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur vrai : la taille de la cellule est adaptée à la taille de l’image qu'elle contient. Si aucune image n’est liée, la cellule n'est pas redimensionnée.
  • pv valeur faux : la taille de la cellule ne varie pas en fonction de la taille de l’image qui lui est liée.
pv style vert alignment Entier long 30 Permet de fixer l'alignement vertical du contenu de la cellule. Valeurs associées : constantes du thème PV Valeurs style.
  • pv valeur align ver haut : applique un alignement vertical en haut à la cellule.
  • pv valeur align ver centré : applique un alignement vertical centré à la cellule.
  • pv valeur align ver bas : applique un alignement vertical bas à la cellule.

Si vous souhaitez définir les propriétés des feuilles de styles par défaut, passez une constante du thème PV Style valeurs spéciales dans le paramètre style :

Constante Type Valeur Comment
pv style cells Entier long -1 Feuille de style par défaut nommée “Cellules”, appliquée aux cellules.
pv style col row headers Entier long -2 Feuille de style par défaut nommée “En-têtes de lignes/colonnes”, appliquée aux en-têtes de colonnes et de lignes.
pv style page footer header Entier long -3 Feuille de style par défaut nommée “En-tête et pied de page”, appliquée à l’en-tête et au pied de page lors de l’impression.
Note : Ces feuilles de styles sont accessibles via la commande Feuilles de style du menu Format de 4D View.

Exemple  

Cette méthode permet de définir les propriétés d’un nouveau style. Dans cet exemple, nous allons définir une valeur pour chacune des trois propriétés de styles à personnaliser :

  • la propriété "alignement horizontal" prendra la valeur "à gauche",
  • la propriété "alignement vertical" prendra la valeur "centré",
  • la propriété "rotation" prendra la valeur "90 degrés".

 ARRAY LONGINT($TabPropriétés;3) `Tableau de propriétés de la feuille de style
 ARRAY LONGINT($TabValeurs;3) `Valeur de chaque propriété
 
 C_TEXT($NomStyle) `Nom de style à ajouter à la Zone
 
 ARRAY LONGINT($TabNumStyles;0) `Tableau des numéros de styles
 ARRAY TEXT($TabNomStyles;0) `Tableau des noms de styles
 C_LONGINT($Indice) `Indice de boucle
 C_LONGINT($Position) `Position du nouveau style dans les tableaux de numéros et de noms
 
  `Initialisations
 $TabPropriétés{1}:=pv style hor alignment  `Propriétés...
 $TabPropriétés{2}:=pv style vert alignment
 $TabPropriétés{3}:=pv style rotation
 
 $TabValeurs{1}:=pv value hor alignment left  `...et valeurs correspondantes
 $TabValeurs{2}:=pv value vert alignment center
 $TabValeurs{3}:=pv value rotation 90
 
 $NomStyle:="Sous-paragraphe"
 
 PV GET STYLE LIST(Zone;$TabNumStyles;$TabNomStyles)  `Liste des styles disponibles
 
 If(Find in array($TabNomStyles;$NomStyle)=-1)  `Style $NomStyle absent ?
    $Position:=Size of array($TabNomStyles)+1  `Nous allons l'ajouter
    INSERT IN ARRAY($TabNomStyles;$Position)  `Redimensionnement des tableaux
    INSERT IN ARRAY($TabNumStyles;$Position)
    $TabNomStyles{$Position}:=$NomStyle  `Affectation du nom du nouveau style
    $TabNumStyles{$Position}:=PV Add style(Zone;$NomStyle)  `Affectation du numéro du nouveau style
 
    For($Indice;1;Size of array($TabPropriétés))  `Pour toutes les propriétés à définir
       If(PV Get style property(Zone;$TabNumStyles{$Position};$TabPropriétés{$Indice})#$TabValeurs{$Indice})
          PV SET STYLE PROPERTY(Zone;$TabNumStyles{$Position};$TabPropriétés{$Indice};$TabValeurs{$Indice})
       End if   `Propriété n'ayant pas la valeur souhaitée ?
    End for  `Passage en revue du tableau $TabPropriétés des propriétés de la feuille de style
 
 Else
    ALERT("Le style '"+$NomStyle+"' est déjà présent pour la zone.")
 End if



Voir aussi  

PV Get style property

Page préc.
Page suiv.

 
PROPRIÉTÉS 

Produit : 4D View
Thème : PV Style
Numéro : 15891

 
HISTORIQUE 

Créé : 4D View 6.8

 
UTILISATION DE L'ARTICLE

4D View - Langage ( 4D View v16)