PV SET CELL FORMULA

4D View v16

PV SET CELL FORMULA


PV SET CELL FORMULA ( area ; coluna ; linha ; formula )

Parâmetro	Tipo	Descrição
area	Inteiro longo	Área 4D View
coluna	Inteiro longo	Número de coluna da célula
linha	Inteiro longo	Número de linha da célula
formula	String	Fórmula

Descrição

O comando PV SET CELL FORMULA localiza formula na célula designada por coluna e linha.

O seguinte exemplo cria um aumento debaixo de uma célula de tipo numérico. Se o valor desta última se modifica posteriormente, o incremento se atualiza automaticamente pela ação das fórmulas que localizamos nas células com PV SET CELL FORMULA.

 C_LONGINT($CopyNumber) //Número de cópias a executar

 C_LONGINT($Column;$Row) //Coordenadas da célula a copiar

 C_LONGINT($Index) //índice de loop

 C_TEXT($Name) //Nome da célula de início

 

 PV GET CURRENT CELL(Area;$Column;$Row)

 If(PV Get cell value type(Area;$Column;$Row)=pv number type value) //Verificação do tipo

  //5 como padrão

    $CopyNumber:=Num(Request("Quantas células para baixo deseja incrementar?";"5"))

    If($CopyNumber>0) //Validar

       $Name:=PV Get cell name(Area;$Column;$Row) //Obter nome

       If($Name="") //Sem nome?

          $Name:="COL"+String($Column)+"RW"+String($Row) //Atualmente tem um nome

          PV SET CELL NAME(Area;$Column;$Row;$Name) //nome de tipo "COL2RW3"

       End if

       For($Index;$Row+1;$Row+$CopyNumber) //loop $CopyNumber

  //Increase

          PV SET CELL FORMULA(Area;$Column;$Index;"="+$Name+"+"+String($Index-$Row))

       End for

    End if

 Else //Tipo incorreto

    ALERT("The start cell must be a numeric type")

 End if

Ver também

PV Get cell formula
PV Get cell value type

4D View v16

PV SET CELL FORMULA

PV SET CELL FORMULA

Descrição

Exemplo