4D Doc Center : REGENERATE MISSING TABLE

Home

4D v14.3

REGENERATE MISSING TABLE


REGENERATE MISSING TABLE ( TabellenName )

Parameter	Typ	Beschreibung
TabellenName	Text	Name der fehlenden Tabelle, die erneut generiert werden soll.

Beschreibung

Der Befehl REGENERATE MISSING TABLE regeneriert die fehlende Tabelle, deren Name im Parameter TabellenName übergeben ist. Die regenerierte Tabelle wird im Struktureditor sichtbar und die darin enthaltenen Daten sind wieder zugänglich.

Fehlende Tabellen sind Tabellen, deren Daten in der Datendatei vorhanden sind, die jedoch nicht auf der Strukturebene existieren.

Über den Befehl GET MISSING TABLE NAMES können Sie fehlende Tabellen, die u.U. in der Anwendung enthalten sind, identifizieren.
Ist die Tabelle, angegeben im Parameter TabellenName, keine fehlende Tabelle der Anwendung, führt der Befehl nichts aus.

Beispiel

Nachfolgende Methode regeneriert alle fehlenden Tabellen, die evtl. in der Anwendung vorhanden sind:

 ARRAY TEXT($arrMissingTables;0)

 GET MISSING TABLE NAMES($arrMissingTables)

 $SizeArray:=Size of array($arrMissingTables)

 If($SizeArray#0)

  //Füllt das Array mit den Namen aller Tabellen in der Anwendung

    ARRAY TEXT(arrTables;Get last table number)

    If(Get last table number>0) //Gibt es derzeit Tabellen

       For($vlTables;Size of array(arrTables);1;-1)

          If(Is table number valid($vlTables))

             arrTables{$vlTables}:=Table name($vlTables)

          Else

             DELETE FROM ARRAY(arrTables;$vlTables)

          End if

       End for

    End if

    For($i;1;$SizeArray)

       If(Find in array(arrTables;$arrMissingTables{$i})=-1)

          CONFIRM("Regeneriere die Tabelle"+$arrMissingTables{$i}+"?")

          If(OK=1)

             REGENERATE MISSING TABLE($arrMissingTables{$i})

          End if

       Else

          ALERT("Tabelle "+$arrMissingTables{$i}+" lässt sich nicht regenerieren, da die Anwendung bereits eine Tabelle mit diesem Namen enthält.")

       End if

    End for

 Else

    ALERT("Keine Tabellen zu regenerieren.")

 End if