4D Doc Center : Operadores de Hora

4D v14.3

Operadores de Hora

Uma expressão que utiliza um operador de horas devolve uma hora ou um número, dependendo da operação. A seguinte tabela mostra os operadores de horas:

Operação	Sintaxe	Devolve	Expressão	Valor
Adição	Hora+ Hora	Hora	?02:03:04? + ?01:02:03?	?03:05:07?
Subtração	Hora– Hora	Hora	?02:03:04? – ?01:02:03?	?01:01:01?
Adição	Hora + Número	Número	?02:03:04? + 65	7449
Subtração	Hora – Número	Número	?02:03:04? – 65	7319
Multiplicação	Hora * Número	Número	?02:03:04? * 2	14768
Divisão	Hora / Número	Número	?02:03:04? / 2	3692
Divisão inteira	Hora \ Número	Número	?02:03:04? \ 2	3692
Módulo	Hora % Hora	Hora	?20:10:00? % ?04:20:00?	?02:50:00?
Módulo	Hora % Número	Número	?02:03:04? % 2	0

Exemplo 1

Pode combinar expressões de tipo hora e de tipo numérico utilizando os comandos Time e Time string. Por exemplo:

  //A seguinte linha atribui a variável $vlSegundos o número de segundos que passarão entre a meia noite e uma hora a partir de agora

 $vlSeconds:=Current time+3600

  //A linha seguinte atribui a $vHSoon a hora que será em uma hora

 $vhSoon:=Time(Current time+3600)

A segunda linha pode ser escrita de uma forma mais simples:

  //A linha seguinte atribui a $vhSoon a hora que será em uma hora

 $vhSoon:=Current time+?01:00:00?

Algumas situações poderiam requerer que você converta uma expressão de tempo em uma expressão numérica.
Por exemplo, você abre um documento utilizando Open document, o qual devolve um número de referência de documento (DocRef) que é uma expressão de tipo hora. Mais adiante, você quer passar DocRef a uma rotina de plug-in 4D que espera um valor numérico como número de referência de documento. Em tal caso, utilize a adição com 0 (zero) para obter um valor numérico de um valor de hora, mas sem mudar seu valor. Por exemplo:

  ` Selecionar e abrir um documento

 $vhDocRef:=Open document("")

 If(OK=1)

  ` Passe a expressão hora DocRef como uma expressão numérica para uma rotina de extensão 4D

    DO SOMETHING SPECIAL(0+$vhDocRef)

 End if

Exemplo 3

O operador Módulo permite adicionar horas levando em conta o formato 24 horas de um dia:

 $t1:=?23:00:00? // São as 23:00 p.m.

  // Queremos adicionar 2 horas e meia

 $t2:=$t1 +?02:30:00? // Com uma adição simples, $t2 é ?25:30:00?

 $t2:=($t1 +?02:30:00?)%?24:00:00? // $t2 é ?01:30:00? e são as 1:30 a.m. do seguinte dia

4D v14.3

Operadores de Hora

Operadores de Hora

Exemplo 1

Exemplo 2

Exemplo 3