4D Doc Center : WR INSERT HYPERLINK

4D Write v14

WR INSERT HYPERLINK


WR INSERT HYPERLINK ( area ; tipoEnlace ; estiloURL ; etiquetaEnlace ; contenidoEnlace ; refMetodo )

Parámetro	Tipo	Descripción
area	Entero largo	Área 4D Write
tipoEnlace	Entero	Tipo de enlace hipertexto: 0 = Método, 1 = URL, 2 = Documento 4D Write
estiloURL	Entero	Apariencia del URL: 1 = Estilo por defecto, 0 = Estilo personalizado
etiquetaEnlace	Texto	Etiqueta del enlace (modo Vista/Valores)
contenidoEnlace	Texto	Contenido del enlace
refMetodo	Entero largo	Valor para $3, tercer parámetro del método (si el enlace es un método)

Descripción

El comando WR INSERT HYPERLINK inserta dentro del área una referencia de tipo "enlace hipertexto", en la ubicación actual del cursor o en el lugar de la selección actual.

tipoEnlace

El parámetro tipoEnlace define el tipo de enlace hipertexto a insertar. 4D Write permite tres tipos de enlaces hipertexto: los enlaces de tipo método, los enlaces de tipo URL y los enlaces de tipo documento.

Un enlace de tipo método ejecuta un método 4D cuando se hace clic en la referencia. El método no puede ser una función y no es posible pasar parámetros. Sin embargo, puede recibir dos o tres valores en $1, $2 y opcionalmente $3:
- $1 (Entero largo) contiene la referencia del área 4D Write,
- $2 (Texto) contiene la etiqueta del enlace,
- $3 (Entero largo) contiene un valor numérico arbitrario que puede asociarse con un enlace utilizando el parámetro refMetodo o través de la interfaz de usuario de la base.
  Con miras a la compilación de la base, es necesario declarar $1 y $3 como Enteros largos y $2 como Texto, incluso si no se utilizan.
  Para añadir un enlace de tipo de método, ponga 0 en tipoEnlace.
Un enlace de tipo URL abre el navegador por defecto y accede a una URL específica, definida en el parámetro contenidoEnlace. Para añadir un enlace de tipo URL, ponga 1 en tipoEnlace.
Un enlace de tipo document sustituye, una vez hace clic en el enlace, el documento actual por otro documento cuya ruta se definió en el parámetro contenidoEnlace. Por supuesto, el formato del documento a abrir debe ser reconocido por 4D Write. Para insertar un enlace de tipo Document, ponga 2 en tipoEnlace.

En el parámetro tipoEnlace, pase una de las siguientes constantes, que se encuentran en tema "WR Parámetros":

Constante	Tipo	Valor
wr method type link	Entero largo	0
wr URL type link	Entero largo	1
wr document type link	Entero largo	2

estiloURL:
El parámetro estiloURL permite definir la apariencia del enlace hipertexto insertado. En este parámetro, puede pasar una de las siguientes constantes del tema "WR Parámetros":

Constante	Tipo	Valor
wr custom link appearance	Entero largo	0
wr default link appearance	Entero largo	1

Si utiliza la constante wr custom link appearance y no define el estilo del enlace, el enlace aparecerá como texto actual (no se materializará gráficamente).

etiquetaEnlace:
El parámetro etiquetaEnlace define el texto visible del enlace (en modo Vista/Valores).

contenidoEnlace:
El parámetro contenidoEnlace contiene el valor hipertexto del enlace. La naturaleza de este valor depende del tipo de enlace:

Para un enlace de tipo método 4D, pase el nombre del método (por ejemplo "Order_Clients"),
Para un enlace de tipo URL, pase el URL completo (por ejemplo “http://www.4D.com/”)
En el caso de un enlace de tipo Document, pase la ruta completa del documento (por ejemplo, "C:\MiCarpeta\MyDoc.4w7" en Windows o "DiscoDuro:MiCarpeta:MyDoc" en Mac OS).

refMetodo:
El parámetro methodRef permite, cuando el enlace es de tipo método 4D, agregar un valor adicional al método llamado. El método recibirá este valor en el parámetro $3 (de tipo Entero largo).

Ejemplo 1

Usted quiere insertar el URL de su sitio web en el área 4D Write:

WR INSERT HYPERLINK(area;wr URL type link;wr default link appearance;"Visite el sitio";"http:/www.MySite.com/")

Ejemplo 2

En sus documentos 4D Write, usted propone una interfaz de navegación hipertexto basada en los enlaces de tipo document. El siguiente método maneja dinámicamente las rutas de acceso, sin importar la plataforma:

 $Doc:=Structure file

 Doc:=$Doc

 While(Position(":";$Doc)#0)

    $Doc:=Substring($Doc;1+Position(":";$Doc);Length($Doc))

    $Long:=Length($Doc)

 End while

 Doc:=Substring(Doc;1;Length(Doc)-$Long)

 PLATFORM PROPERTIES($Platf;$Syst;$Computer)

 If($Platf=Windows)

    $name:=Doc+"Documentation"+"/"+"01_Introduction.4W7"

 Else

    $name:=Doc+"Documentation"+":"+"01_Introduction.4W7"

 End if

 $title:="See Documentation"

 WR INSERT HYPERLINK(Writearea;wr document type link;wr default link appearance;$title;$name)

Ejemplo 3

Este ejemplo ilustra el empleo de enlaces de tipo método. En su documento, usted quiere que el usuario pueda introducir la información, por ejemplo su nombre y apellido, en una ubicación específica. Para hacerlo, inserte un enlace que llame al método Hyperlink_Method. Este método pide al usuario introducir su nombre o apellido, dependiendo del valor pasado en $3. Los datos introducidos se remplazarán por el enlace:

  `Hyperlink_Method

 C_LONGINT($1;$3)

 C_TEXT($2)

 Case of

    :($3=1)

       WR INSERT TEXT($1;Request("Escriba su nombre"))

    :($3=2)

       WR INSERT TEXT($1;Request("Escriba su apellido"))

 End case

 WR GET SELECTION($1;$deb;$end)

 WR SET SELECTION($1;$deb;$end+1)

 WR EXECUTE COMMAND($1;wr cmd clear)

Para insertar el enlace de tipo de método en el área 4D Write:

 $title:="Haga clic en introducir"

 $method:="Hyperlink_Method"

 WR INSERT TEXT(Area;"Apellido: ")

 WR INSERT HYPERLINK(Area;wr method type link;wr default link appearance;$title;$method;1)

 WR INSERT TEXT(Area;Char(Carriage return)+"Nombre: ")

 WR INSERT HYPERLINK(Area;wr method type link;wr default link appearance;"Haga clic para introducir";"Hyperlink_Method";2)