4D Doc Center : PV TABLEAU VERS CELLULES

4D View v14

PV TABLEAU VERS CELLULES


PV TABLEAU VERS CELLULES ( zone ; direction ; colonne ; ligne ; conversion ; tableau )

Paramètre	Type	Description
zone	Entier long	Zone 4D View
direction	Entier	0 = Ligne; 1 = Colonne
colonne	Entier long	Numéro de la colonne de départ
ligne	Entier long	Numéro de la ligne de départ
conversion	Entier	0 = Type texte; 1 = Type inchangé
tableau	Tableau	Nom de tableau

Description

La commande PV TABLEAU VERS CELLULES insère dans zone le contenu du tableau passé en sixième paramètre. Le contenu est inséré à partir des coordonnées définies par colonne et ligne, dans le sens indiqué par le paramètre direction.

Note : L’usage du paramètre direction est différent de celui du paramètre direction des commandes PV ALLER A CELLULE SUIVANTE et PV LIRE CELL LIBRE SUIVANTE, pour lesquelles la direction peut être dans n'importe quel sens. En ce qui concerne la commande PV TABLEAU VERS CELLULES, la direction est soit vers la droite (0 = ligne), soit vers le bas (1 = colonne).

Le cinquième paramètre, conversion, permet de retyper le contenu des cellules de destination en texte. Le type de la valeur source doit être compatible avec cette opération : si vous demandez le retypage d’un BLOB ou d’une image en texte, conversion sera ignoré.

Exemple

Recopie vers le bas (sens vertical) de trois tableaux de types différents à partir de la cellule courante. En fonction de la réponse au dialogue de confirmation de transformation de genre, le contenu des tableaux peut être affecté aux cellules de 4D View sous forme convertie (texte) ou non.

 C_ENTIER($Indice) `Indice de la boucle

 C_ENTIER LONG($Colonne;$Ligne) `Coordonnées de la cellule de départ

 C_ENTIER($Conversion) `Forcer la conversion en texte ?

 

 TABLEAU ALPHA(20;$TabAlpha;10) `Tableau des valeurs alphanumériques (commence à la cellule courante)

 TABLEAU DATE($TabDates;10) `Tableau des dates (colonne suivante)

 TABLEAU BOOLEEN($TabBooléens;10) `Tableau des booléens (troisième colonne)

 

  `Initialisation

 Boucle($Indice;1;Taille tableau($TabAlpha))

    $TabAlpha{$Indice}:=Chaine($Indice*10) `"10", "20", "30"...

    $TabDates{$Indice}:=Date du jour(*)+$Indice  `25/06/2001, 26/06/2001...

    $TabBooléens{$Indice}:=($Indice%2=0) `Vrai = pair

 Fin de boucle

 

 PV LIRE CELLULE COURANTE(Zone;$Colonne;$Ligne)

 

 CONFIRMER("Voulez-vous convertir le contenu des tableaux en texte ?")

 $Conversion:=1-OK

 

  `Pour obtenir les colonnes "$TabAlpha", "$TabDates" et "$TabBooléens" :

 PV TABLEAU VERS CELLULES(Zone;1;$Colonne;$Ligne;$Conversion;$TabAlpha) `1 = vers le bas

 PV TABLEAU VERS CELLULES(Zone;1;$Colonne+1;$Ligne;$Conversion;$TabDates)

 PV TABLEAU VERS CELLULES(Zone;1;$Colonne+2;$Ligne;$Conversion;$TabBooléens)