4D Doc Center : PV REPORT MANY

Home

4D View v14

PV REPORT MANY


PV REPORT MANY ( Bereich ; Spalte ; Zeile ; Haupttabelle ; TabelleUmbruch ; FeldUmbruch ; Operator ; Tabellen ; Felder ; Einfügen ; Detail ; Titel )

Parameter	Typ	Beschreibung
Bereich	Lange Ganzzahl	4D View Bereich
Spalte	Lange Ganzzahl	Spaltennummer
Zeile	Lange Ganzzahl	Zeilennummer
Haupttabelle	Ganzzahl	Nummer Haupttabelle
TabelleUmbruch	Ganzzahl	Nummer der Tabelle, wo Umbruch passiert
FeldUmbruch	Array	Nummer des Feldes, wo Umbruch passiert
Operator	Array Ganzzahl	Auszuführende Operationen
Tabellen	Array Ganzzahl	Tabellennummer der anzuzeigenden Felder
Felder	Array Ganzzahl	Nummer der anzuzeigenden Felder
Einfügen	Ganzzahl	0 = Ersetzen; 1 = Zeilen einfügen
Detail	Ganzzahl	Detail Einfügeoptionen
Titel	String	Umbruchtitel

Beschreibung

Der Befehl PV REPORT MANY erstellt einen Bericht im 4D View Bereich mit den Werten aus 4D Feldern, angegeben in Tabellen und Felder, beginnend mit der aktuellen Auswahl der Tabelle Haupttabelle. Auf jedes dieser Felder lässt sich eine Operation, definiert durch Operator ausführen: Zwischensumme, Zahl, Maximum, etc. Für den Parameter Operator verwenden Sie eine Konstante unter dem Thema PV Bericht Funktionen :

Konstante	Typ	Wert
pv report function average	Lange Ganzzahl	1
pv report function count	Lange Ganzzahl	4
pv report function max	Lange Ganzzahl	3
pv report function min	Lange Ganzzahl	2
pv report function none	Lange Ganzzahl	-1
pv report function sum	Lange Ganzzahl	0

Das generierte Ergebnis fügen Sie aus der Zelle Spalte und Zeile in Bereich ein.

TabelleUmbruch und FeldUmbruch weist das Feld zu, wo der Umbruch ausgeführt wird. Über Umbrüche können Sie Datensätze in homogene Gruppen einteilen und Zwischenberechnungen ausführen.
Ein Umbruch ist eine Wertänderung in einer Sortierung nach Tabelle. Sie müssen diese Umbruchebene einer Sortierung nach Kriterium zuweisen. Die Datensatzauswahl definiert durch TabelleUmbruch und FeldUmbruch muss vor Einsatz des Befehls PV REPORT MANY sortiert werden. Sie kann auch weitere Sortierkriterien enthalten, die für den Umbruch keine Bedeutung haben. Weitere Informationen zum Erstellen von Schnellberichten finden Sie im Handbuch 4D Designmodus.

Der Parameter Einfügen gibt an, ob die im 4D View Bereich gesetzten Werte bereits vorhandene Zellen ersetzen oder in neue Zeilen eingegeben werden. Übergeben Sie den Wert 0 (Null), werden die Daten gelöscht und ersetzt, übergeben Sie 1, werden zusätzliche Zeilen eingefügt.

Mit dem Parameter Detail können Sie festlegen, wie 4D View Daten und Umbruchzeilen im Bericht einfügt:

Übergeben Sie 0 in Detail, werden nur Umbruchzeilen eingefügt und keine Zeilen mit Daten.
Übergeben Sie 1 in Detail, werden Zeilen mit Daten eingefügt und der Umbruchwert in jeder Zeile wiederholt.
Übergeben Sie 2 in Detail, werden Zeilen mit Daten eingefügt und der Umbruchwert nur einmal angezeigt.

Mit dem Parameter Titel können Sie den Titel der Ergebniszeile setzen, z.B. "Gesamt", "Durchschnitt". Sie können wie im 4D Schnellberichteditor das Zeichen # als Platzhalter für den Wert des aktuellen Umbruchs verwenden. Ist zum Beispiel “Land” das Umbruchfeld, übergeben Sie in Titel "Gesamt für #:". Der Bericht zeigt dann an: "Gesamt für USA: "Gesamt für Japan:", etc.
Übergeben Sie einen leeren String, wenn Sie keinen Titel einfügen wollen.

Hinweis: Hat Detail den Wert 0 und ist der Titel ein leerer String, wird die erste Spalte nicht eingefügt, da sie leer wäre.

Beispiel

Sie zeigen in einem eingebundenen 4D View Bereich im Eingabeformular Kunden einen Bericht mit Kontakten zu diesem Kunden. Der Umbruch zeigt die Anzahl Kontakte pro Titel: Sekretärin, Entwickler, Vertrieb, etc. Es gibt eine automatische Verknüpfung zwischen der Tabelle Kontakte und der Tabelle Titel.

 C_LONGINT($Column) `Spaltennummer

 C_LONGINT($Row) `Zeilennummer

 C_INTEGER($Master) `Haupttabelle Nummer

 C_INTEGER($TableBreak) `Nummer Tabelle, wo Umbruch auftritt

 C_INTEGER($FieldBreak) `Nummer Feld, wo Umbruch auftritt

 ARRAY INTEGER($Operator;3) `Auszuführende Operationen

 ARRAY INTEGER($Tables;3) `Tabellennummer für die anzuzeigenden Felder

 ARRAY INTEGER($Fields;3) `Anzahl der anzuzeigenden Felder

 C_INTEGER($Insert) `0=Ersetzen;1=Zeilen einfügen

 C_INTEGER($Detail) `Optionen für Detailanzeige

 C_STRING(30;$Title) `Titel für sich ergebende Zeile

 

  `Initialisieren

 $Column:=4 `Starte Anzeige mit Spalte D

 $Row:=3 `Starte Anzeige mit der 3. Zeile (Titel + leere Zeile)

 $Master:=Table(->[Contacts]) `Dies ist ein "Bericht" der Tabelle Kontakte

 $TableBreak:=Table(->[Titles])

 $FieldBreak:=Field(->[Titles]Label) `Umbruch tritt auf bei Titel Kontakte

 

  `Zeige in Spalte 1 die Nummer für jeden Typ

 $Operator{1}:=pv report function count

 $Tables{1}:=Table(->[Titles])

 $Fields{1}:=Field(->[Titles]Label) `Bezeichnung für Titel Spalte 1

 

 $Operator{2}:=pv report function none `Keine Berechnung in Spalte 2

 $Tables{2}:=Table(->[Contacts])

 $Fields{2}:=Field(->[Contacts]ContactName) `Name des Kontakts Spalte 2

 

 $Operator{3}:=pv report function none `Keine Berechnung in Spalte 3

 $Tables{3}:=Table(->[Contacts])

 $Fields{3}:=Field(->[Contacts]ContactFirstname) `Vorname des Kontakts Spalte 3

 

 $Insert:=1 `Einfügen

 $Detail:=2 `Zeilen mit Daten werden eingefügt, Werte werden einmal angezeigt

 $Title:="Anzahl Kontakte für #" ` # wird ersetzt durch aktuellen Wert des Umbruchs

 

 RELATE MANY([Clients]Code) `Erhalte Kundencode

  `Sortierung notwendig bei Umbruch + Anzeige in alphabetischer Reihenfolge

 ORDER BY([Contacts];[Titles]Label;[Contacts]ContactName;[Contacts]ContactFirstname)

 

 PV REPORT MANY(Bereich;$Column;$Row;$Master;$TableBreak;$FieldBreak;$Operator;$Tables;

 $Fields;$Insert;$Detail;$Title)

Aktuelle Auswahl und Datensätze

Die Auswahl richtet sich nach den Verknüpfungen zwischen Tabellen auf der Strukturebene der Datenbank sowie Feldnummern und Arrays, die im Befehl als Parameter übergeben wurden.